সারসংক্ষেপএকাধিক কর বন্ধনীগুলির উপর ভিত্তি করে মোট আয়কর গণনা করতে, আপনি VLOOKUP এবং উদাহরণে দেখানো হিসাবে কাঠামোযুক্ত একটি রেট টেবিল ব্যবহার করতে পারেন। G5 এর সূত্র হল:
= VLOOKUP (inc,rates,3,1)+(inc- VLOOKUP (inc,rates,1,1))* VLOOKUP (inc,rates,2,1)
যেখানে 'inc' (G4) এবং 'হার' (B5: D11) নামযুক্ত রেঞ্জ , এবং কলাম D হল a সহায়ক কলাম যা প্রতিটি বন্ধনীতে মোট সঞ্চিত কর গণনা করে।
পটভূমি এবং প্রসঙ্গ
মার্কিন কর ব্যবস্থা হল 'প্রগতিশীল', যার অর্থ উচ্চ করযোগ্য আয়ের মানুষ উচ্চতর ফেডারেল কর হার প্রদান করে। হারগুলি একটি উপরের এবং নিম্ন প্রান্তিক প্রান্ত দ্বারা সংজ্ঞায়িত বন্ধনীতে মূল্যায়ন করা হয়। প্রদত্ত বন্ধনীতে যে পরিমাণ আয় পড়ে তা সেই বন্ধনীটির জন্য সংশ্লিষ্ট হারে কর ধার্য করা হয়। করযোগ্য আয় বৃদ্ধির সাথে সাথে আয়কে আরো কর বন্ধনীতে কর আরোপ করা হয়। অনেক করদাতা তাই বিভিন্ন হারে অর্থ প্রদান করেন।
দেখানো উদাহরণে, করের বন্ধনী এবং হারগুলি 2019 সালের কর বছরের জন্য মার্কিন যুক্তরাষ্ট্রে একক ফাইলকারীদের জন্য। নীচের টেবিলে $ 50,000 এর করযোগ্য আয়ের ম্যানুয়াল গণনা দেখানো হয়েছে:
| বন্ধনী | হিসাব | কর |
|---|---|---|
| 10% | ($ 9,700 - $ 0) x 10% | $ 970.00 |
| 12% | ($ 39,475 - $ 9,700) x 12% | $ 3,573.00 |
| 22% | ($ 50,000- $ 39,475) x 22% | $ 2,315.50 |
| 24% | এনএ | $ 0.00 |
| 32% | এনএ | $ 0.00 |
| 35% | এনএ | $ 0.00 |
| 37% | এনএ | $ 0.00 |
মোট কর তাই $ 6,858.50। (দেখানো উদাহরণে 6,859 হিসাবে প্রদর্শিত)।
সেটআপ নোট
1. এই সূত্রটি নির্ভর করে VLOOKUP ফাংশন 'আনুমানিক ম্যাচ মোডে'। যখন আনুমানিক মিল মোডে থাকে, VLOOKUP একটি সারণিতে সন্ধানের মানগুলির মাধ্যমে স্ক্যান করবে (যা আরোহী ক্রমে সাজানো উচিত) যতক্ষণ না একটি উচ্চ মান পাওয়া যায়। তারপর এটি 'স্টেপ ব্যাক' হবে এবং আগের সারি থেকে একটি মান ফেরত দেবে। একটি সঠিক মিলের ক্ষেত্রে, VLOOKUP মিলে যাওয়া সারি থেকে ফলাফল ফেরত দেবে।
2. VLOOKUP- এর প্রকৃত ক্রমবর্ধমান করের পরিমাণ পুনরুদ্ধারের জন্য, এগুলিকে একটি হিসাবে টেবিলে যুক্ত করা হয়েছে সহায়ক কলাম কলাম ডি -তে D6- এর সূত্রটি কপি করা হয়েছে,
=((B6-B5)*C5)+D5
প্রতিটি সারিতে, এই সূত্রটি উপরের সারি থেকে সেই বন্ধনীতে আয়ের রেট প্রয়োগ করে।
রেঞ্জ ভিবিএতে প্রতিটি কক্ষের জন্য
3. পাঠযোগ্যতার জন্য, নিম্নলিখিত নামযুক্ত রেঞ্জ , সংজ্ঞায়িত করা হয়েছে: 'inc' (G4) এবং 'হার' (B5: D11)।
ব্যাখ্যাG5 এ, প্রথম VLOOKUP এই ইনপুটগুলির সাথে প্রান্তিক হারে ক্রমবর্ধমান কর পুনরুদ্ধারের জন্য কনফিগার করা হয়েছে:
- সন্ধানের মান হল 'inc' (G4)
- সন্ধানের টেবিল হল 'হার' (B5: D11)
- কলাম নম্বর 3, ক্রমবর্ধমান কর
- মিলের ধরন 1 = আনুমানিক মিল
VLOOKUP (inc,rates,3,1) // returns 4,543
$ 50,000 এর করযোগ্য আয়ের সাথে, VLOOKUP, আনুমানিক ম্যাচ মোডে, 39,475 এর সাথে মিলিত হয় এবং 4,543 ফেরত দেয়, মোট কর $ 39,475 পর্যন্ত।
দ্বিতীয় VLOOKUP করের বাকি আয়ের হিসাব করে:
(inc- VLOOKUP (inc,rates,1,1)) // returns 10,525
এইভাবে গণনা করা হয়:
(50,000-39,475) = 10,525
অবশেষে, তৃতীয় VLOOKUP (শীর্ষ) প্রান্তিক কর হার পায়:
VLOOKUP (inc,rates,2,1) // returns 22%
এটি আগের ধাপে গণনা করা আয় দ্বারা গুণিত হয়। সম্পূর্ণ সূত্র এইভাবে সমাধান করা হয়:
= VLOOKUP (inc,rates,3,1)+(inc- VLOOKUP (inc,rates,1,1))* VLOOKUP (inc,rates,2,1) =4,543+(10525)*22% =6,859
প্রান্তিক এবং কার্যকর হার
VLOOKUP- এর সাথে গণনা করা সেল G6 শীর্ষ প্রান্তিক হার ধারণ করে:
= VLOOKUP (inc,rates,2,1) // returns 22%
G7 তে কার্যকর কর হার হল মোট কর করযোগ্য আয় দ্বারা বিভক্ত:
=G5/inc // returns 13.7%
দ্রষ্টব্য: আমি দৌড়ে গিয়েছিলাম জেফ লেনিং এর ব্লগে এই সূত্র এক্সেল বিশ্ববিদ্যালয়ে। VLOOKUP আনুমানিক ম্যাচ মোডে কিভাবে ব্যবহার করা যায় এবং একই সূত্রে VLOOKUP কিভাবে একাধিকবার ব্যবহার করা যায় তার একটি দুর্দান্ত উদাহরণ।
লেখক ডেভ ব্রুনস
