সূত্র

প্রতি nম সারির যোগফল

Prati Nma Sarira Yogaphala

প্রতি nম সারির যোগফল

  এক্সেল সূত্র: প্রতি nম সারির যোগফল জেনেরিক সূত্র
=SUM(FILTER(data,MOD(SEQUENCE(ROWS(data)),n)=0))
সারসংক্ষেপ

প্রতিটি nম সারির যোগফল (অর্থাৎ প্রতি দ্বিতীয় সারি, প্রতি তৃতীয় সারি, ইত্যাদি) আপনি এর উপর ভিত্তি করে একটি সূত্র ব্যবহার করতে পারেন ফিল্টার ফাংশন , দ্য MOD ফাংশন , এবং SUM ফাংশন . দেখানো উদাহরণে, সেল F6 এর সূত্র হল:





=SUM(FILTER(B5:B16,MOD(SEQUENCE(ROWS(B5:B16)),F5)=0))

সেল F5 এর 3 নম্বর সহ n , ফলাফল হল 70।

ব্যাখ্যা

এই উদাহরণে, লক্ষ্য হল প্রতিটি nম মানকে ডেটার পরিসরে যোগ করা, যেমনটি উপরে দেখানো ওয়ার্কশীটে দেখা গেছে। উদাহরণস্বরূপ, যদি n =2, আমরা প্রতিটি সেকেন্ড মান (প্রতিটি অন্য মান) যোগ করতে চাই, যদি n =3, আমরা তৃতীয় মান যোগ করতে চাই, ইত্যাদি। মধ্যে এক্সেলের সর্বশেষ সংস্করণ , এটি করার সবচেয়ে সহজ উপায় হল FILTER ফাংশন ব্যবহার করা। ভিতরে উত্তরাধিকার এক্সেল, নিচে ব্যাখ্যা করা SUMPRODUCT ফাংশনের উপর ভিত্তি করে আপনি একটি বিকল্প সূত্র ব্যবহার করতে পারেন।





সমস্ত ডেটা B5:B16 এবং n সেল F5 এ 3 হিসাবে প্রবেশ করা হয়।

উদাহরণ সূত্র

দেখানো উদাহরণে, সেল F6 এর সূত্র হল:



=SUM(FILTER(B5:B16,MOD(SEQUENCE(ROWS(B5:B16)),F5)=0))

উচ্চ স্তরে, এই সূত্রটি প্রতিটি nম সারি বা ডেটার সাথে সম্পর্কিত মানগুলি বের করতে FILTER ফাংশন ব্যবহার করে এবং SUM ফাংশনটি নিষ্কাশিত মানগুলির যোগফল ফেরাতে ব্যবহার করে।

ডেটা বের করা হচ্ছে

ভিতর থেকে কাজ করা, এই সমস্যার প্রথম ধাপ হল ডেটা সংগ্রহ করা যা সংকলন করা উচিত। এই সঙ্গে করা হয় ফিল্টার ফাংশন এটার মত:

FILTER(B5:B16,include)

কোথায় অন্তর্ভুক্ত প্রতিটি nম মান (উদাহরণে প্রতিটি 3য় মান) লক্ষ্য করার জন্য প্রয়োজনীয় সূত্র যুক্তি উপস্থাপন করে। আমাদের প্রয়োজনীয় যুক্তি তৈরি করতে, আমরা MOD ফাংশন এবং SEQUENCE ফাংশনের সংমিশ্রণ ব্যবহার করি:

MOD(SEQUENCE(ROWS(B5:B16)),F5)=0)

ROWS ফাংশন B5:B16 রেঞ্জে সারির গণনা প্রদান করে, যা হল 12:

MOD(SEQUENCE(12),F5)=0)

12 সারি যুক্তি হিসাবে, সঙ্গে SEQUENCE ফাংশন একটি সংখ্যা প্রদান করে অ্যারে এই মত 12 সংখ্যার মধ্যে:

{1;2;3;4;5;6;7;8;9;10;11;12}

উপরের অ্যারে এবং n (3) এর মানকে আমাদের সূত্রে প্রতিস্থাপন করা:

যদি অন্যথায় এক্সেল হয়
MOD({1;2;3;4;5;6;7;8;9;10;11;12},3)=0)

দ্য MOD ফাংশন 3 দ্বারা বিভক্ত অ্যারের প্রতিটি সংখ্যার অবশিষ্টাংশ ফেরত দেয়:

{1;2;0;1;2;0;1;2;0;1;2;0}=0

MOD-এর ফলাফল শূন্যের সাথে তুলনা করা হয়, এবং ফলাফল হল TRUE এবং FALSE মানগুলির একটি অ্যারে:

এক্সেল সূত্রটি যদি ঘরে নির্দিষ্ট পাঠ্য না থাকে
{FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE}

মনে রাখবেন যে প্রতি 3য় মানটি সত্য। এটি FILTER-এ ফেরত দেওয়া মান হিসাবে অন্তর্ভুক্ত যুক্তি. FILTER এই অ্যারেটি B5:B16 ব্যাপ্তির মানগুলিকে 'ফিল্টার' করতে ব্যবহার করে। শুধুমাত্র TRUE এর সাথে যুক্ত মানগুলি ফিল্টার অপারেশনের মাধ্যমে এটি তৈরি করে। ফলাফলটি একটি অ্যারে যা ডেটাতে প্রতিটি 3য় মান রয়েছে:

{20;15;10;25}

FILTER মানগুলির এই বিন্যাসটি সরাসরি SUM ফাংশনে সরবরাহ করে, যা চূড়ান্ত ফলাফল হিসাবে যোগফল (70) প্রদান করে। এই সূত্রটি গতিশীল। উদাহরণ স্বরূপ, যদি কোষ F5-এ n-এর মান 2-এ পরিবর্তিত হয় (প্রতি 2য় মান) তাহলে নতুন ফলাফল হল 120।

লিগ্যাসি এক্সেল সূত্র

ভিতরে এক্সেলের পুরানো সংস্করণ যেগুলি FILTER বা SEQUENCE ফাংশনগুলিকে অন্তর্ভুক্ত করে না, আপনি SUMPRODUCT ফাংশনের উপর ভিত্তি করে একটি ভিন্ন সূত্র ব্যবহার করতে পারেন:

=SUMPRODUCT(--(MOD(ROW(B5:B16)-ROW(B5)+1,F5)=0),B5:B16)

ধারণাটি উপরে বর্ণিত সূত্রের মতই কিন্তু পদ্ধতি ভিন্ন। শুধু নির্দিষ্ট মান বের করার পরিবর্তে, এই সূত্রটি 'শূন্য আউট' অন্যান্য মান প্রথমত, সূত্রটি সারি সংখ্যার একটি আপেক্ষিক সেট তৈরি করতে ROW ফাংশন ব্যবহার করে:

ROW(B5:B16)-ROW(B5)+1

এই মত একটি সংখ্যাসূচক অ্যারে প্রদান করে:

{1;2;3;4;5;6;7;8;9;10;11;12}

SUMPRODUCT ফাংশনের ভিতরে, আমরা আবার একটি ফিল্টার তৈরি করতে MOD ফাংশন ব্যবহার করি:

=MOD(ROW(B5:B16)-ROW(B5)+1,F5)=0
=MOD({1;2;3;4;5;6;7;8;9;10;11;12},F5)=0

এবং MOD এই মত TRUE FALSE মানগুলির একটি অ্যারে প্রদান করে:

{FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE}

আবার, মনে রাখবেন যে প্রতি 3য় মান সত্য। ক ডবল নেতিবাচক (--) TRUE এবং FALSE মানগুলিকে 1s এবং 0s-এ রূপান্তর করতে ব্যবহৃত হয়:

=SUMPRODUCT({0;1;0;1;0;1;0;1;0;1;0;1},B5:B16)

SUMPRODUCT তারপর দুটি অ্যারেকে একসাথে গুণ করে এবং পণ্যের যোগফল প্রদান করে। শুধুমাত্র B5:B6-এর মানগুলি যা 1s-এর সাথে যুক্ত এই ক্রিয়াকলাপটি বেঁচে থাকে। অন্যান্য মানগুলি 'শূন্য করা হয়েছে':

=SUMPRODUCT({0;0;20;0;0;15;0;0;10;0;0;25}) // returns 70

চূড়ান্ত ফলাফল হল 70। এই সূত্রটিও গতিশীল। সেল F5-এ n-এর মান 2-এ পরিবর্তিত হলে (প্রতি 2য় মান) নতুন ফলাফল হল 120।

লেখক ডেভ ব্রান্স


^