সূত্র

ত্রৈমাসিক দ্বারা সমষ্টি

Traimasika Dbara Samasti

ত্রৈমাসিক দ্বারা সমষ্টি

  এক্সেল সূত্র: ত্রৈমাসিক দ্বারা সমষ্টি জেনেরিক সূত্র
=SUMIFS(values,quarters,A1)
সারসংক্ষেপ

ত্রৈমাসিক দ্বারা মান যোগ করতে, আপনি উপর ভিত্তি করে একটি সূত্র ব্যবহার করতে পারেন SUMIFS ফাংশন সঙ্গে a সহায়ক কলাম যে কোয়ার্টার আছে. দেখানো উদাহরণে, G5 এর সূত্র হল:





=SUMIFS(data[Amount],data[Qtr],F5)

কোথায় তথ্য একটি এক্সেল টেবিল B5:D16 রেঞ্জে, এবং কলাম E-এর কোয়ার্টারগুলি নীচে বিস্তারিত আরেকটি সূত্র তৈরি করেছে।

ব্যাখ্যা

এই উদাহরণে, লক্ষ্য হল ত্রৈমাসিক নির্ণয় করতে কলাম B-এর তারিখগুলি ব্যবহার করে ত্রৈমাসিক দ্বারা কলাম সি-তে পরিমাণগুলি যোগ করা। F কলামে কোয়ার্টার নম্বরগুলি ম্যানুয়ালি প্রবেশ করানো হয়। চূড়ান্ত ফলাফল জি কলামে উপস্থিত হওয়া উচিত। সমস্ত ডেটা নামের একটি এক্সেল টেবিলে রয়েছে তথ্য B5:E16 পরিসরে। এই সমস্যাটি দিয়ে সমাধান করা যেতে পারে SUMIFS ফাংশন এবং একটি হেল্পার কলাম, অথবা ব্যবহার করে একটি হেল্পার কলাম ছাড়া SUMPRODUCT ফাংশন . উভয় পন্থা নীচে ব্যাখ্যা করা হয়.





কোয়ার্টার গণনা করা হচ্ছে

এই সমস্যার প্রথম ধাপ হল B কলামে প্রতিটি তারিখের জন্য কোয়ার্টার তৈরি করা। দেখানো টেবিলে, কলাম D হল একটি সহায়ক কলাম ত্রৈমাসিক সংখ্যার সাথে একটি পৃথক সূত্র গণনা করা হয়েছে। D5 এর সূত্র, কপি ডাউন, হল:

=ROUNDUP(MONTH([@Date])/3,0) // get quarter

দ্রষ্টব্য: কারণ আমরা একটি ব্যবহার করছি এক্সেল টেবিল ডেটা ধরে রাখতে, আমরা স্বয়ংক্রিয়ভাবে পাই কাঠামোগত রেফারেন্স উপরে দেখা যায়। রেফারেন্স [@Date] মানে: তারিখ কলামে বর্তমান সারি। আপনি যদি স্ট্রাকচার্ড রেফারেন্সে নতুন হন তবে এই ছোট ভিডিওটি দেখুন: কাঠামোগত রেফারেন্সের ভূমিকা .



এক্সেল উপস্থাপন মূল্য কিভাবে

দ্য MONTH ফাংশন প্রতিটি তারিখের জন্য 1-12 এর মধ্যে একটি মাসের সংখ্যা প্রদান করে, যা 3 দ্বারা বিভক্ত রাউন্ডআপ ফাংশন তারপর ফলাফলটিকে নিকটতম পূর্ণ সংখ্যায় রাউন্ড আপ করতে ব্যবহৃত হয়। এই সূত্র হল এখানে আরো বিস্তারিতভাবে ব্যাখ্যা করা হয়েছে .

SUMIFS সমাধান

সমস্যার পরবর্তী ধাপ হল ডি কলামে কোয়ার্টার নম্বর ব্যবহার করে কলাম সি-তে পরিমাণ যোগ করা। এটি সহজেই করা যেতে পারে SUMIFS ফাংশন . SUMIFS ফাংশনটি পরিসরে মান যোগ করার জন্য ডিজাইন করা হয়েছে শর্তসাপেক্ষে একাধিক মানদণ্ডের উপর ভিত্তি করে। SUMIFS ফাংশনের স্বাক্ষর এই মত দেখায়:

=SUMIFS(sum_range,range1,criteria1,range2,criteria2,...)

লক্ষ্য করুন সমষ্টি_পরিসীমা প্রথমে আসে, তারপরে পরিসীমা/মাপদণ্ড জোড়া আর্গুমেন্টের প্রতিটি ব্যাপ্তি/মাপদণ্ড অন্য শর্ত উপস্থাপন করে।

এই ক্ষেত্রে, আমাদের শুধুমাত্র একটি শর্ত ব্যবহার করে কোয়ার্টার নম্বর দ্বারা মানের সমষ্টি করার জন্য SUMIFS কনফিগার করতে হবে: আমাদের F কলামের কোয়ার্টারে একটি ম্যাচের জন্য কলাম D-এ কোয়ার্টার পরীক্ষা করতে হবে। আমরা শুরু করি সমষ্টি_পরিসীমা :

=SUMIFS(data[Amount]

পরবর্তী, আমরা একটি হিসাবে মানদণ্ড যোগ করুন পরিসীমা/মাপদণ্ড জোড়া, কোথায় criteria_range1 হয় তারিখ কলাম, এবং মানদণ্ড 1 F কলামে ত্রৈমাসিক সংখ্যা হল:

=SUMIFS(data[Amount],data[Qtr],F5)

সূত্রটি কপি করা হলে, আমরা F কলামে প্রতিটি ত্রৈমাসিকের জন্য মোট পাই।

সাহায্যকারী ছাড়া SUMPRODUCT

এই ধরনের SUMPRODUCT ফাংশন সহ সাহায্যকারী কলাম ছাড়া এই সমস্যাটি সমাধান করাও সম্ভব:

এক্সেল এ লগ 2 গণনা কিভাবে
=SUMPRODUCT((ROUNDUP(MONTH(data[Date])/3,0)=F5)*data[Amount])

ভিতর থেকে কাজ করলে, SUMPRODUCT-এর ভিতরে অভিব্যক্তির প্রথম অংশটি তারিখ কলামে প্রতিটি তারিখের জন্য একটি চতুর্থাংশ সংখ্যা তৈরি করে:

ROUNDUP(MONTH(data[Date])/3,0)

এটি মূলত একই সূত্র উপরে ব্যবহার করা হয়, পার্থক্য আমরা খাওয়ানো MONTH ফাংশন সমগ্র তথ্য[তারিখ] একটি কক্ষের পরিবর্তে কলাম। কারণ কলামে 12টি তারিখ আছে, আমরা একটি ফিরে পাই অ্যারে এতে 12 মাসের সংখ্যা এইরকম রয়েছে:

{1;2;3;4;5;6;7;8;9;10;11;12}

এই অ্যারেটি ROUNDUP ফাংশনে বিতরণ করা হয় সংখ্যা যুক্তি:

ROUNDUP({1;2;3;4;5;6;7;8;9;10;11;12}/3,0)

এবং ROUNDUP 12 কোয়ার্টার সংখ্যার একটি অ্যারে প্রদান করে:

{1;1;1;2;2;2;3;3;3;4;4;4}

দ্রষ্টব্য: আমরা সরলতার জন্য এই উদাহরণে একটি খুব ছোট ডেটা সেট ব্যবহার করছি, কিন্তু একই পদ্ধতি শত শত বা হাজার হাজার তারিখ পরিচালনা করবে।

এরপরে, ROUNDUP-এর অ্যারেটিকে F5 এর সাথে তুলনা করা হয় এবং ফলাফল হল একটি অ্যারে যাতে 12টি TRUE এবং FALSE মান রয়েছে৷ যখন এই অ্যারেটি দ্বারা গুণিত হয় তথ্য [পরিমাণ] , গণিত অপারেশন সত্য এবং মিথ্যা মান 1s এবং 0s এ পরিবর্তন করে। এই মুহুর্তে, আমাদের আছে:

=SUMPRODUCT({1;1;1;0;0;0;0;0;0;0;0;0}*data[Amount])

দুটি অ্যারেকে একসাথে গুণ করলে একটি একক অ্যারে পাওয়া যায়। এই অ্যারেতে, শুধুমাত্র 1 ত্রৈমাসিকের সাথে যুক্ত পরিমাণ টিকে থাকে — অন্যান্য ত্রৈমাসিকের জন্য রাশি কার্যকরভাবে 'শূন্য-আউট':

=SUMPRODUCT({127;130;450;0;0;0;0;0;0;0;0;0})

প্রক্রিয়া করার জন্য শুধুমাত্র একটি অ্যারে সহ, SUMPRODUCT অ্যারের মানগুলিকে যোগ করে এবং একটি চূড়ান্ত ফলাফল প্রদান করে, 707। সূত্রটি কলাম G নিচে অনুলিপি করা হয়, এটি প্রতিটি ত্রৈমাসিকের জন্য মোট প্রদান করে, কোন সাহায্যকারী কলামের প্রয়োজন নেই।

লেখক ডেভ ব্রান্স


^